# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Jayvee Enaguas <harvettfox96@dismail.de>

pkgname=pciutils
pkgver=3.7.0
_debver=3.7.0
_debrel=5
pkgrel=test1
pkgdesc="PCI bus configuration space access library and tools"
url="https://mj.ucw.cz/sw/pciutils"
license=('GPL-2')
arch=('x86_64' 'i686')
groups=('base')
depends=('hwids' 'kmod')
makedepends=('quilt')
source=("https://www.kernel.org/pub/software/utils/${pkgname}/${pkgname}-${pkgver}.tar."{xz,sign}
        "https://deb.debian.org/debian/pool/main/p/${pkgname}/${pkgname}_$_debver-$_debrel.debian.tar.xz")
sha512sums=('eaae09a1a91137f026aaa7484baa6fb138146dbe58a7fd5eb4cd38f206426a123b27e397c8f6a62eaef627470bff109365cd137a04358ec6a4539da342661f26'
            'SKIP'
            '19573d8f6bbbef35b02ee1b8bf8a0f713b54e36d07f22993dd051da5b80066903d22d13d8466f8f554b580061142c42714843371373b8c2c3c2794b7213c72e9')
validpgpkeys=('5558F9399CD7836850553C6EC28E7847ED70F82D') # Martin Mares <mj@ucw.cz>

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ $pkgver = $_debver ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # doesn't apply
    rm -v debian/patches/00-configure*.patch || true
    rm -v debian/patches/hurd-flags-arg.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}

  make \
    OPT="${CFLAGS} -fPIC -DPIC" \
    ZLIB=no \
    SHARED=no \
    PREFIX=/usr \
    SHAREDIR=/usr/share/hwdata \
    MANDIR=/usr/share/man \
    lib/libpci.a

  cp -a lib/libpci.a "${srcdir}"

  make clean
  make \
    OPT="${CFLAGS}" \
    ZLIB=no \
    SHARED=yes \
    PREFIX=/usr \
    SHAREDIR=/usr/share/hwdata \
    MANDIR=/usr/share/man \
    all
}

package() {
  cd ${pkgname}-${pkgver}

  make \
    SHARED=yes \
    PREFIX=/usr \
    SHAREDIR=/usr/share/hwdata \
    MANDIR=/usr/share/man \
    DESTDIR="${pkgdir}" \
    install install-lib

  # move lspci and setpci to /usr/bin
  mkdir -p "$pkgdir"/usr/bin
  mv "$pkgdir"/usr/sbin/{ls,set}pci "$pkgdir"/usr/bin
  # move libraries to /lib
  mkdir -p "$pkgdir"/lib
  mv "$pkgdir"/usr/lib/libpci.so.${pkgver::1}* "$pkgdir"/lib
  ln -sf /lib/libpci.so.${pkgver::1} "$pkgdir"/usr/lib/libpci.so
  # this is now supplied by the hwids package
  rm -rf $pkgdir/usr/share/hwdata
  # install license
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/${pkgname}
}